Myanmar IT Resource Forum
Myanmar IT Resource Forum

You are not connected. Please login or register

View previous topic View next topic Go down  Message [Page 1 of 1]

1 Customize Windows XP Boot CD with batch file on 26th February 2010, 1:21 pm

kyawzwathant


MITR Reader



MITR Reader
Code:
ကၽြန္ေတာ္ Windows XP SP3 Boot CD ကို nLite နဲ႕လုပ္တာ ေတာ္ေတာ္ေလးအဆင္ေျပတယ္။ Service pack, drivers, hot fix အကုန္ေပါင္းတာ ရတယ္။ ဒါေပမယ္ ေနာက္အဆင့္တစ္ခု လိုအပ္ေနတယ္ အဲ့ဒါက Batch command ေရးပီး software installation လုပ္ခ်င္တာ မရေသးဘူးျဖစ္ေနတယ္။ registry ကို လည္း input လုပ္ခ်င္တယ္။ တခ်ဳိ႕ software ေလးေတြ ေပါင္းထည့္ ေပးခ်င္တယ္ hacker ေတြလုပ္ထားတဲ့ windows xp boot cd ေတြလိုမ်ဳိးေပါ့။ MS Live Messenger, Gtalk, Skype, Windows Media Player 11, IE 8, Mozilla Firefox, Office, etc... စသျဖင့္ေပါ့။ အဲ့ဒါေတြကို ဘယ္လိုေရးပီး run ခိုင္းရမလဲ။
1. ပထမအဆင့္က Windows Installation လုပ္မယ္ဗ်ာ
2. ဒုတိယအဆင့္က software ေတြကို installation လုပ္မယ္ဗ်ာ
အဲ့ဒါေတြကို CD, DVD တစ္ခုထည္းမွာ ေပါင္းထည့္ေပးခ်င္တာ
      hacker ေတြလုပ္ထားတဲ့ CD , DVD ေတြမွာက batch file processing နဲ႕ တဆင့္ခ်င္းခိုင္းထားတာ copy ကူးပီး လုပ္ခိုင္းလို႕လဲ မရဘူး။ သူတို႕ အိုင္ဒီယာက တစ္မ်ဳိး ကၽြန္ေတာ္ လုပ္ခ်င္တာက တစ္မ်ဳိးဗ်။ သူတို႕က မလိုအပ္တာေတြ အမ်ားႀကီးထည့္ထားတယ္။ ကၽြန္ေတာ္တို႕အတြက္ အသံုးမတည့္တာေတြမ်ားတယ္။ အဲဒါ ကူညီေပးႏိုင္ၾကရင္ ကူညီၾကပါဦး။
ကၽြန္ေတာ္မွာ Windows XP SP3 untouch original Copy CD ရွိတယ္ အထက္က ကၽြန္ေတာ္လုပ္ထားတာေတြ အကုန္ဆင္ေျပတယ္။ ေနာက္ထပ္တိုးခ်င္တာ အဆင္မေျပဘူးျဖစ္ေနတယ္။

ဒါက သူတို႕ေရးထားတဲ့ batch file ပါ


Code:
@echo off

rem Original Source from Winstyle 2008 Big Thank ^^
rem OEMinfo For Windows Dark Edition v.7 Rebirth Version

setlocal ENABLEEXTENSIONS ENABLEDELAYEDEXPANSION
set OEMFILE=%SYSTEMROOT%\system32\oeminfo.ini
set REGMODE=0
set TAGFILE=WIN51
set MANUFACTURER=Windows Dark Edition V.7
set MODEL=Rebirth Version By Catalogk
set UPMAX=6
set UPNAMEL=8
set KEY=0
set KEYISVISIBLE=1
for %%d in (c d e f g h i j k l m n o p q r s t u v w x y z) do (if exist "%%d:\%TAGFILE%" set CDROM=%%d:&& goto metka)
:metka

if defined CDROM (
   set UPDATESDIR=%CDROM%\Systems\WinDa7k_ALL\I386\SVCPACK
   set UPDATESMASK=*.*
) else (
   set CDROM=%~dp0
   set CDROM=!CDROM:~0,-7!
   set UPDATESDIR=%SYSTEMROOT%\system32\CatRoot\{F750E6C3-38EE-11D1-85E5-00C04FC295EE}
   set UPDATESMASK=KB*.*
)

for /F "tokens=1" %%j in ('reg 2^>nul') do if "%%j"=="REG" set REGEXE=rus

if exist "%CDROM%\I386\winn?.sif" (
   set WINNTSIF=%CDROM%\I386\winn?.sif
) else (
   if defined REGEXE (
      for /F "tokens=3 delims=   " %%j in ('reg query "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion" /v SourcePath') do set SrcP=%%j
   ) else (
      for /F "tokens=3 delims= " %%j in ('reg query "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion" /v SourcePath') do set SrcP=%%j
   )
   if exist "!SrcP!\winn?.sif" set WINNTSIF=!SrcP!\winn?.sif
)

if defined REGEXE (
   for /F "tokens=3 delims=   " %%j in ('reg query "HKCU\Control Panel\International" /v Locale') do set lang=%%j
   for /F "tokens=3 delims=   " %%j in ('reg query "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion" /v ProductName') do set PN=%%j
   for /F "tokens=3 delims=   " %%j in ('reg query "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion" /v CSDVersion') do set CSDV=%%j
   for /F "tokens=3 delims=   " %%j in ('reg query "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion" /v CurrentVersion') do set CV=%%j
   for /F "tokens=3 delims=   " %%j in ('reg query "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion" /v BuildLab') do set BUILD=%%j
) else (
   for /F "tokens=3 delims= " %%j in ('reg query "HKCU\Control Panel\International" /v Locale') do set lang=%%j
   for /F "tokens=3* delims= " %%j in ('reg query "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion" /v ProductName') do set PN=%%j %%k
   for /F "tokens=3* delims= " %%j in ('reg query "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion" /v CSDVersion') do set CSDV=%%j %%k
   for /F "tokens=3 delims= " %%j in ('reg query "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion" /v CurrentVersion') do set CV=%%j
   for /F "tokens=3 delims= " %%j in ('reg query "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion" /v BuildLab') do set BUILD=%%j
)

for /F %%j in ('echo.%* ^| find /i /c "/k"') do if %%j==1 set KEY=1
for /F %%j in ('echo.%* ^| find /i /c "/v"') do if %%j==1 set KEYISVISIBLE=1
for /F %%j in ('echo.%* ^| find /i /c "/r"') do if %%j==1 set REGMODE=1

echo [General]> "%OEMFILE%"
echo Manufacturer=%MANUFACTURER%>> "%OEMFILE%"
echo Model=%MODEL%>> "%OEMFILE%"

if defined WINNTSIF (
   if %KEY% == 1 (
      for /F "tokens=3 delims==] " %%j in ('find /I /N "ProductKey" "%WINNTSIF%"') do set PK=%%j
   )
)

set i=1
set l=0
set c=0
set n=0

if %REGMODE% == 1 (

   for /F "tokens=5* delims=\" %%j in ('reg query "HKLM\SOFTWARE\Microsoft\Updates" /s ^| findstr /i /v "REG_ FileList"') do (
      if %ERRORLEVEL%==0 (
         for /F "usebackq tokens=3 delims=\" %%m in ('%%j\%%k') do (
            set tmp=%%m         
            set tmp=!tmp:~0,%UPNAMEL%!
            set kb[!tmp!]=!tmp:~2,6!
         )
         for /F "tokens=2 delims=\" %%m in ('echo %%j\%%k^| findstr /i /c:" .NET"') do (
            set tmp=%%m         
            set tmp=!tmp:~0,%UPNAMEL%!
            set kb[!tmp!]=!tmp:~2,6!
         )
      )
   )
   for /F "tokens=7 delims=\" %%m in ('reg query "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall" ^| findstr /i "\<KB[0-9][0-9][0-9][0-9][0-9][0-9]"') do (
      set tmp=%%m         
      set tmp=!tmp:~0,%UPNAMEL%!
      set kb[!tmp!]=!tmp:~2,6!
   )
   for /F %%j in ('set kb[') do set /A n+=1
   
   call :suppinfo
   
   for /F "tokens=2 delims=[]" %%j in ('set kb[ ^| sort') do (set kbname=%%j&& call :myprint)
) else (

   for /F %%j in ('dir /b /a:-d "%UPDATESDIR%\%UPDATESMASK%"') do set /A n+=1
   
   call :suppinfo
   
   for /F "tokens=1 delims=." %%j in ('dir /b /a:-d "%UPDATESDIR%\%UPDATESMASK%"') do (set kbname=%%j&&set kbname=!kbname!          &&set kbname=!kbname:~0,%UPNAMEL%!&& call :myprint)
)

goto :EOF

:myprint
if !c! == 0 (
   set str=!kbname!
) else (
   set str=!str!  !kbname!
)

set /A c+=1

if !c! == %UPMAX% (
   echo Line!i!=!str!>> "%OEMFILE%"
   set /A i+=1
   set /A l+=1
   set str=
   set c=0
   set /A tmp=n-l*UPMAX
) else (
   if %n% LSS %UPMAX% (
      if !c! == %n% (
         echo Line!i!=!str!>> "%OEMFILE%"
      )
   )
   if !tmp! LSS %UPMAX% (
      if !c! == !tmp! (
         echo Line!i!=!str!>> "%OEMFILE%"
      )
   )
)
goto :EOF

:suppinfo
if defined PK (
   if %KEYISVISIBLE% == 0 (
      echo [OEMSpecific]>> "%OEMFILE%"
      echo SerialNo=%PK%>> "%OEMFILE%"
      )
   )
)

echo [Support Information]>> "%OEMFILE%"

   
echo Line!i!=Windows Dark Edition v.7 Rebirth Version By Catalogk>> "%OEMFILE%"
rem set /A i+=1

if defined PK (
   if %KEYISVISIBLE% == 1 (
         echo Line!i!=Product Key: %PK%>> "%OEMFILE%"
      set /A i+=1
   )
)
echo Line!i!=>> "%OEMFILE%"
set /A i+=1

for /F %%t in ('time/T') do set T=%%t
   
   echo Line!i!=OS:%PN:Microsoft=% %CSDV:Service Pack=SP% version %CV% build %BUILD%>> "%OEMFILE%"
   rem set /A i+=1
   rem echo Line!i!=>> "%OEMFILE%"
    set /A i+=1
   echo Line!i!=Installation ^(updation^) date and time: %date% ^(%T%^)>> "%OEMFILE%"
    set /A i+=1
    echo Line!i!=>> "%OEMFILE%"
    set /A i+=1
    echo Line!i!=Contact : [You must be registered and logged in to see this link.]>> "%OEMFILE%"
    set /A i+=1
    echo Line!i!=>> "%OEMFILE%"
    set /A i+=1
   echo Line!i!=Installed Components and Updates ^(%n%^):>> "%OEMFILE%"

set /A i+=1
echo Line!i!=>> "%OEMFILE%"
set /A i+=1
goto :EOF

2 Re: Customize Windows XP Boot CD with batch file on 27th February 2010, 5:01 pm

sHa92


Founder



Founder
အစ္ကို လုပ္ခ်င္ေနတာလားခင္ဗ်ာ။

အေပၚဆုံးက Quote က ဘယ္သူ ေရးထားတာလဲဟင္။ တၿခားက ကူးၿပတာလား။ အစ္ကိုေရးထားတာလား?

အစ္ကိုၿပတဲ့ Bat Codes ေတြကေတာ့ တကယ့္ bat ဂြ်တ္စ္ေတြ ေရးထားတာေလ။ Very Happy
Logic ဘဲလုိမွာ ေရးတာကေတာ့ လြယ္ပါတယ္။ သူတုိ႔ေရးထားတာကိုေတာ့ ထပ္မတုိးနဲ႔ Code ေတြ လြဲကုန္ရင္ ဘာမွ အလုပ္မလုပ္ဘဲ ၿဖစ္ကုန္မယ္။
ကိုယ္တုိင္ စဥ္းစားၿပီး Process တစ္ခုၿခင္းစီ အတြက္ ေရးၾကည့္တာက Debug လုပ္ရင္လည္း လြယ္လိမ့္မယ္။

Windows is the Longest Batch File of the World ဆုိတဲ့ ဟာသေလး ရယ္ ၊ Bat နဲ႔ အားလုံးလုပ္လုိ႔ရတယ္ဆုိတာ အခု Code နဲ႔တင္ သက္ေသၿပလို႔ရေနပါတယ္။ Very Happy Very Happy



Change We Need!
http://www.myanmaritresource.info

3 Re: Customize Windows XP Boot CD with batch file on 27th February 2010, 8:04 pm

kyawzwathant


MITR Reader



MITR Reader
အေပၚဆံုးက code က အကိုေရးတာ တင္တာ

ေအာက္က batch code ေတြကေတာ့ ကူးတင္ေပးတာ

အဲ့ဒါက OEM Logo နဲ႕ သူတို႕ရဲ႕ My Computer Properties မွာေပၚေအာင္လုပ္ထားတာကို ကူးတင္ေပးလိုက္တာ

batch file က 2 file ရွိတယ္ 1 file က ျပန္ရွာေနတာ ေနရာမမွတ္မိေတာ့လို႕

အခုတင္ေပးလိုက္တာက မွားတင္တာ နမူနာျပခ်င္တဲ့ ဖိုင္က ဘယ္မွာ သိမ္းထားမွန္းမမွတ္မိေတာ့ဘူး ရွာေနတယ္။

ေတြ႕ရင္ျပန္တင္ေပးမယ္။ အခုလမ္းစေတာ့ နည္းနည္းေတြ႕ေနျပီ။

$OEM$ folder လုပ္ျပီး အဲ့ဒီအထဲမွာ installation software ေတြထည့္ျပီး batch file ေရးရမွာ အဲ့ဒါကို စာဖတ္ျပီး

စမ္းၾကည့္ေနတယ္ ။

အေပၚက batch file က Thai Hacker ေတြလုပ္ထားတာလို႕ထင္တယ္ အဲ့ဒီ Windows XP regional setting မွာ Thai language - default လုပ္ထားတယ္ CD ဆိုင္ေတြမွာေတာ့ DarkXP v7

ဆို၀ယ္လို႕ရတယ္ ။ ေတာ္ေတာ္ေလးေကာင္းတယ္ Windows7 Theme လုပ္ထားတာ ။

ေနာက္တစ္ခုက Air-boot ဆိုတာပါတယ္ အဲ့ဒါလည္း Linux boot နဲ႕ လုပ္ထားတာ ေတာ္ေတာ္ေကာင္းတယ္ ။

အင္တာနက္ထဲမွာလည္းရွိတယ္ ။

4 Re: Customize Windows XP Boot CD with batch file on 27th February 2010, 8:10 pm

sHa92


Founder



Founder
ေအာ္။ဟုတ္ကဲ့/ ကိုယ္တုိင္လုပ္တာေတာ့ အေကာင္းဆုံးေပါ့ဗ်ာ။ Very Happy
စမ္းလုိက္။ ရလာတာကို ၿပန္မွ်ေ၀လိုက္ေပါ့။ Smile



Change We Need!
http://www.myanmaritresource.info

5 Re: Customize Windows XP Boot CD with batch file on 27th February 2010, 8:15 pm

kyawzwathant


MITR Reader



MITR Reader
အခုတင္ေပးလိုက္တဲ့ ဟာကေတာ့ မူရင္း CD က ပါတာမဟုတ္ဘူး web site တစ္ခုက ကူးထားတာ ဘယ္ကမွန္း မမွတ္မိေတာ့ဘူး ဖတ္ၾကည့္ပါဦး .....

Code:
CLS
@echo off
TITLE Windows XP SP2 - Unattended Installation

ECHO.
ECHO Over the next few minutes you will see automated installations
ECHO of various sofware applications, windows updates, and registry
ECHO tweaks being implemented. The computer will restart automatically
ECHO once the whole process has finished!

ECHO.
ECHO Removing Wallpapers and Screensavers...
DEL "%systemroot%*.bmp"
DEL "%systemroot%WebWallpaper*.jpg"
DEL "%systemroot%system32dllcache*.scr"
DEL "%systemroot%system32*.scr"

ECHO.
ECHO Removing useless shortcuts...
DEL "%systemdrive%Documents and SettingsAll UsersStart MenuWindows Update.lnk"
DEL "%systemdrive%Documents and SettingsAll UsersStart MenuSet Program Access and Defaults.lnk"
DEL "%systemdrive%Documents and SettingsAll UsersStart MenuWindows Catalog.lnk"

ECHO.
ECHO Installing MSN Messenger 6.0.0602 Final
ECHO Please wait...
start /wait %systemdrive%installMSNMsnMsgs.msi /qn

ECHO.
ECHO Installing TweakUI 2.10 Powertoy
ECHO Please wait...
start /wait %systemdrive%installPowertoysTweakUI.msi /qn

ECHO.
ECHO Installing Task Switcher Powertoy
ECHO Please wait...
start /wait %systemdrive%installPowerToysTaskswitchPowertoySetup.exe /s /v/qn

ECHO.
ECHO Applying Registry Tweaks...
REGEDIT /S %systemdrive%installRegTweaks.reg

ECHO.
ECHO Deleting ASP.NET User Account created by .NET Framework 1.1...
net user aspnet /delete

ECHO.
ECHO Starting installation of Applications

ECHO.
ECHO Installing Diskeeper 7.0.428
ECHO Please wait...
start /wait %systemdrive%installApplicationsdiskeeperSetup.exe /s /v/qn

ECHO.
ECHO Installing Flashget 1.4
ECHO Please wait...
start /wait %systemdrive%installApplicationsflashgetfgf140.exe /S

ECHO.
ECHO Registering Flashget 1.4...
REGEDIT /S %systemdrive%installApplicationsflashgetregister.reg

ECHO.
ECHO Installing Kerio Personal Firewall 2.1.5
ECHO Please wait...
start /wait %systemdrive%installApplicationskpfSetup.exe -s

ECHO.
ECHO Registering Nero Burning ROM...
REGEDIT /S %systemdrive%installApplicationsNeroregister.reg

ECHO.
ECHO Installing Nero Burning ROM v5.5.10.42
ECHO Please wait...
start /wait %systemdrive%installApplicationsNeroNero551042.exe /silent /noreboot

ECHO.
ECHO Installing Symantec Antivirus Corporate 8.1
ECHO Please wait...
start /wait %systemdrive%installApplicationssavsav810b821.exe /qn

ECHO.
ECHO Updating Symantec Antivirus Virus Definitions (May 14th 2003)...
COPY "%systemdrive%installApplicationssavvd155c08.xdb.xdb" "%systemdrive%
Documents and SettingsAll UsersApplication DataSymantec
Norton AntiVirus Corporate Edition7.5"

ECHO.
ECHO Restarting the PC in 1 minute...
shutdown.exe -r -f -t 60 -c "Windows XP will now restart in 1 minute, this will give
enough time for the shortcuts to update and for the shell to fully load before it's ready to restart!"

ECHO.
ECHO Deleting Temp Installation Files...
RD /S /Q %systemdrive%Drivers
RD /S /Q %systemdrive%install

EXIT

6 Re: Customize Windows XP Boot CD with batch file on 27th February 2010, 8:39 pm

kyawzwathant


MITR Reader



MITR Reader
ဒါက ေတာ္ေတာ္ရွင္းတယ္ေနာ္
Code:
cmdow @ /HID
@echo off

SET KEY=HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnceEx

REG ADD %KEY% /V TITLE /D "Installing Applications" /f

REG ADD %KEY%\005 /VE /D "Adobe Reader 6" /f
REG ADD %KEY%\005 /V 1 /D "%systemdrive%\install\AdobeReader6\AR6.msi /qn" /f

REG ADD %KEY%\010 /VE /D "Alcohol 120" /f
REG ADD %KEY%\010 /V 1 /D "%systemdrive%\install\alcohol\setup.exe /qn" /f
REG ADD %KEY%\010 /V 2 /D "REGEDIT /S %systemdrive%\install\alcohol\register.reg" /f

REG ADD %KEY%\015 /VE /D "Diskeeper 8" /f
REG ADD %KEY%\015 /V 1 /D "%systemdrive%\install\DiskeeperPro_8.0.459.exe /s /v/qn" /f

REG ADD %KEY%\050 /VE /D "Importing Registry Tweaks" /f
REG ADD %KEY%\050 /V 1 /D "REGEDIT /S %systemdrive%\install\regtweaks.reg" /f

REG ADD %KEY%\055 /VE /D "Cleaning Up and Rebooting" /f
REG ADD %KEY%\055 /V 1 /D "%systemdrive%\install\cleanup.cmd" /f

EXIT

yarzarmin


MITR New User



ကိုေက်ာ္ဇြာေရ ကြၽန္ေတာ္လဲစမ္းလိုက္ဦမယ္ေနာ္

Tayzakoko


MITR New User



ညီ အစ္ကို ေမာင္နွမေတြေရ
က်ေနာ္ကလဲ ငတံုးပဲဗ် ဒီ bat ဖိုင္ေတြကို ဘရ္လို အသံုးျပဳရတာလဲ
CD boot လုပ္တရ္ဆိုတာေလးနဲ႔ အခု ဒီ bat ဖိုင္ အသံုးျပဳပံုေလးကို
ေျပာျပေပးၾကပါအံုး

http://shwekyintharpoem.blogspot.com

Sponsored content


View previous topic View next topic Back to top  Message [Page 1 of 1]

Permissions in this forum:
You cannot reply to topics in this forum

 

Free forum | © PunBB | Free forum support | Contact | Report an abuse | Free forum